Sap Material tutorials jobs interview questions

This function module and global data was closely modeled after

standard SAP™ function modules such as MASTERIDOC_CREATE_DEBMAS.

This function module was used a skeleton to create the following

function module for distribution of customer hierarchy master IDOCs.

FUNCTION ZMASTERIDOC_CREATE_ZDEBHI.
*"

———————————————————————

-
*"*"Local interface:
*"       IMPORTING
*"             VALUE(KNVHKEY) LIKE ZKNVHKEY STRUCTURE ZKNVHKEY
*"             VALUE(RCVPFC) LIKE BDALEDC-RCVPFC
*"             VALUE(RCVPRN) LIKE BDALEDC-RCVPRN
*"             VALUE(RCVPRT) LIKE BDALEDC-RCVPRT
*"             VALUE(SNDPFC) LIKE BDALEDC-SNDPFC
*"             VALUE(SNDPRN) LIKE BDALEDC-SNDPRN
*"             VALUE(SNDPRT) LIKE BDALEDC-SNDPRT
*"             VALUE(MESSAGE_TYPE) LIKE TBDME-MESTYP
*"       EXPORTING
*"             VALUE(CREATED_COMM_IDOCS) LIKE SY-TABIX
*"

———————————————————————

-
************************MODIFICATION*********************************

***
* Programmer    :   Rajeev

Kasturi                                     *
* This function module is called from the driver FM

:                  *
*

"ZMASTERIDOC_CREATE_SMD_ZDEBHI"..

*
* The processing is based on the change document object

KUNHIER.       *
*********************************************************************

***

DATA: BEGIN OF F_IDOC_HEADER.
INCLUDE STRUCTURE EDIDC.
DATA: END OF F_IDOC_HEADER.

DATA: BEGIN OF T_IDOC_DATA OCCURS 10.
INCLUDE STRUCTURE EDIDD.
DATA: END OF T_IDOC_DATA.

DATA: BEGIN OF T_IDOC_COMM_CONTROL OCCURS 10.
INCLUDE STRUCTURE EDIDC.
DATA: END OF T_IDOC_COMM_CONTROL.

DATA: ACTIVE_FLAG(1) TYPE C.

DATA: COMM_CONTROL_LINES LIKE SY-TABIX.

DATA: IDOC_CIMTYPE LIKE EDIDC-CIMTYP.

DATA: PARTNER_TYPE LIKE TPAR-NRART. "P30K057526

DATA: COUNTRY_ISO LIKE T005-INTCA.

* initial
CLEAR T_IDOC_COMM_CONTROL.
REFRESH T_IDOC_COMM_CONTROL.
CLEAR T_IDOC_DATA.
REFRESH T_IDOC_DATA.

CLEAR IDOC_CIMTYPE.

* fill T_IDOC_DATA for Segment Z1KNVHM with KNVH
SELECT SINGLE * FROM KNVH
WHERE HITYP = KNVHKEY-HITYP
AND KUNNR = KNVHKEY-KUNNR
AND VKORG = KNVHKEY-VKORG
AND VTWEG = KNVHKEY-VTWEG
AND SPART = KNVHKEY-SPART
AND DATAB = KNVHKEY-DATAB.
IF SY-SUBRC = 0.
PERFORM FILL_SEGMENT_Z1KNVHM USING KNVHKEY-MSGFN.
*
CLEAR T_IDOC_DATA.
T_IDOC_DATA-SEGNAM = C_SEGNAM_Z1KNVHM.
T_IDOC_DATA-MANDT = SY-MANDT.
T_IDOC_DATA-SDATA = Z1KNVHM.
*
APPEND T_IDOC_DATA.
ENDIF.
*
* fill IDOC_HEADER
F_IDOC_HEADER-MESTYP = MESSAGE_TYPE.
F_IDOC_HEADER-IDOCTP = C_IDOCTP_ZDEBHI.
F_IDOC_HEADER-CIMTYP = IDOC_CIMTYPE.
F_IDOC_HEADER-SNDPFC = SNDPFC.
F_IDOC_HEADER-SNDPRN = SNDPRN.
F_IDOC_HEADER-SNDPRT = SNDPRT.
F_IDOC_HEADER-RCVPFC = RCVPFC.
F_IDOC_HEADER-RCVPRN = RCVPRN.
F_IDOC_HEADER-RCVPRT = RCVPRT.
F_IDOC_HEADER-SERIAL = SPACE.
*
*
CALL FUNCTION 'MASTER_IDOC_DISTRIBUTE'
EXPORTING
MASTER_IDOC_CONTROL            = F_IDOC_HEADER
TABLES
COMMUNICATION_IDOC_CONTROL     = T_IDOC_COMM_CONTROL
MASTER_IDOC_DATA               = T_IDOC_DATA
EXCEPTIONS
ERROR_IN_IDOC_CONTROL          = 01
ERROR_WRITING_IDOC_STATUS      = 02
ERROR_IN_IDOC_DATA             = 03
SENDING_LOGICAL_SYSTEM_UNKNOWN = 04.

IF SY-SUBRC <> 0.
ENDIF.

DESCRIBE TABLE T_IDOC_COMM_CONTROL LINES COMM_CONTROL_LINES.
CREATED_COMM_IDOCS = COMM_CONTROL_LINES.
ENDFUNCTION.
Figure 5-6: ALE function module for populating and distributing

master IDOCs

Figure 5-7: Global data for the ALE function modules
FUNCTION-POOL ZDEB.                         "MESSAGE-ID ..
*
*
DATA: C_MSGFN_I LIKE Z1KNVHM-MSGFN VALUE '009', "New
C_MSGFN_U LIKE Z1KNVHM-MSGFN VALUE '004', "Change
C_MSGFN_R LIKE Z1KNVHM-MSGFN VALUE '005', "Refresh
C_MSGFN_T LIKE Z1KNVHM-MSGFN VALUE '023', "Synchronisation
C_MSGFN_D LIKE Z1KNVHM-MSGFN VALUE '003', "Deletion
C_MSGFN_S LIKE Z1KNVHM-MSGFN VALUE '018'. "Reissue
DATA:   C_IDOCS_BEFORE_COMMIT LIKE SY-TABIX VALUE 50.
DATA:   C_SEGNAM_Z1KNVHM LIKE EDIDD-SEGNAM VALUE 'Z1KNVHM'.
DATA:   C_IDOCTP_ZCSTHI LIKE BDALEDC-IDOCTP VALUE 'ZKNVHM01'.
TABLES: KNVH, Z1KNVHM.

ALE function module to process Change Pointers

admin — Sun, 30 May 2010 21:16:20 +0000

Note: ABAP/4 is the proprietary programming language of SAP™.

This function module has been modeled after standard SAP™ function modules for processing master data

change pointers, such as MASTERIDOC_CREATE_SMD_DEBMAS. This function module was used as a skeleton for the

following function module for processing customer hierarchy change pointers.

FUNCTION ZMASTERIDOC_CREATE_SMD_ZDEBHI.
*"———————————————————————
*"*"Local interface:
*"       IMPORTING
*"             VALUE(MESSAGE_TYPE) LIKE TBDME-MESTYP
*"———————————————————————
*
************************MODIFICATION************************************
* Programmer    :   Rajeev Kasturi                                     *
* Date          :   Feb. 1998                                          *
* Description   :   This function module has been created anew for     *
* generating Customer Hierarchy IDOCs used in ALE distribution of      *
* changes (creates/changes/deletes) of SD Customer Hierarchy. The new *
* message type for this purpose is ZDEBHI, and the custom "Basic IDOC" *
* type is ZKNVHM01.                                                    *
************************************************************************
DATA: BEGIN OF F_KNVHKEY,
MANDT   LIKE KNVH-MANDT,
HITYP   LIKE KNVH-HITYP,
KUNNR   LIKE KNVH-KUNNR,
VKORG   LIKE KNVH-VKORG,
VTWEG   LIKE KNVH-VTWEG,
SPART   LIKE KNVH-SPART,
DATAB   LIKE KNVH-DATAB,
END OF F_KNVHKEY.
*
DATA: BEGIN OF F_KNVH.
INCLUDE STRUCTURE ZKNVHKEY.
DATA: END OF F_KNVH.
*
DATA: BEGIN OF T_KNVHKEY OCCURS 10.
INCLUDE STRUCTURE ZKNVHKEY.
DATA: END OF T_KNVHKEY.
*
DATA: BEGIN OF T_CHGPTRS OCCURS 10.
INCLUDE STRUCTURE BDCP.
DATA: END OF T_CHGPTRS.

DATA: BEGIN OF T_CPIDENT OCCURS 10,
CPIDENT LIKE BDCP-CPIDENT,
END OF T_CPIDENT.

DATA: BEGIN OF T_CPIDENT_KNVH OCCURS 10,
MANDT   LIKE KNVH-MANDT,
HITYP   LIKE KNVH-HITYP,
KUNNR   LIKE KNVH-KUNNR,
VKORG   LIKE KNVH-VKORG,
VTWEG   LIKE KNVH-VTWEG,
SPART   LIKE KNVH-SPART,
DATAB   LIKE KNVH-DATAB,
CPIDENT LIKE BDCP-CPIDENT,
END OF T_CPIDENT_KNVH.

* created idocs
* SAP created variables – does not follow naming stds.
DATA: CREATED_M_IDOCS LIKE SY-TABIX.
DATA: CREATED_COMM_IDOCS LIKE SY-TABIX.
DATA: CREATED_C_IDOCS LIKE SY-TABIX.
DATA: DONE_SINCE_COMMIT LIKE SY-TABIX.

* read all not processed change pointers for the given messagetype,
* object class KUNHIER
* return code is not checked for since no exception is raised by
* the function module.
CALL FUNCTION 'CHANGE_POINTERS_READ'
EXPORTING
CHANGE_DOCUMENT_OBJECT_CLASS = 'KUNHIER'
MESSAGE_TYPE = MESSAGE_TYPE
READ_NOT_PROCESSED_POINTERS = 'X'
TABLES
CHANGE_POINTERS = T_CHGPTRS.

*
REFRESH T_KNVHKEY.
*
* create all keys from the change pointers
LOOP AT T_CHGPTRS.
*     table KNVH
*     table KNVH of the change document equals the table KNVH
PERFORM MOVE_X_TO_Y USING T_CHGPTRS-TABKEY+0(3)
                  F_KNVHKEY-MANDT.
IF F_KNVHKEY-MANDT = SPACE.
F_KNVHKEY-MANDT = T_CHGPTRS-MANDT.
ENDIF.
*
PERFORM MOVE_X_TO_Y USING T_CHGPTRS-TABKEY+3(1)
                  F_KNVHKEY-HITYP.
*
PERFORM MOVE_X_TO_Y USING T_CHGPTRS-TABKEY+4(10)
                  F_KNVHKEY-KUNNR.
*
PERFORM MOVE_X_TO_Y USING T_CHGPTRS-TABKEY+14(4)
                  F_KNVHKEY-VKORG.
*
PERFORM MOVE_X_TO_Y USING T_CHGPTRS-TABKEY+18(2)
                  F_KNVHKEY-VTWEG.
*
PERFORM MOVE_X_TO_Y USING T_CHGPTRS-TABKEY+20(2)
                  F_KNVHKEY-SPART.
*
PERFORM MOVE_X_TO_Y USING T_CHGPTRS-TABKEY+22(8)
                  F_KNVHKEY-DATAB.
*
READ TABLE T_KNVHKEY WITH KEY F_KNVHKEY.
*
MOVE F_KNVHKEY-MANDT TO T_KNVHKEY-MANDT.
MOVE F_KNVHKEY-HITYP TO T_KNVHKEY-HITYP.
MOVE F_KNVHKEY-KUNNR TO T_KNVHKEY-KUNNR.
MOVE F_KNVHKEY-VKORG TO T_KNVHKEY-VKORG.
MOVE F_KNVHKEY-VTWEG TO T_KNVHKEY-VTWEG.
MOVE F_KNVHKEY-SPART TO T_KNVHKEY-SPART.
MOVE F_KNVHKEY-DATAB TO T_KNVHKEY-DATAB.
*
PERFORM CONVERT_CDCHGID_TO_MSGFN USING T_CHGPTRS-CDCHGID
                               T_KNVHKEY-MSGFN.
IF SY-SUBRC <> 0.
APPEND T_KNVHKEY.
ELSE.
MODIFY T_KNVHKEY INDEX SY-TABIX.
ENDIF.
*
*       add pointer to processed pointers
MOVE-CORRESPONDING F_KNVHKEY TO T_CPIDENT_KNVH.
MOVE T_CHGPTRS-CPIDENT TO T_CPIDENT_KNVH-CPIDENT.
APPEND T_CPIDENT_KNVH.
ENDLOOP.
*
SORT T_KNVHKEY BY MANDT HITYP KUNNR VKORG VTWEG SPART DATAB.
SORT T_CPIDENT_KNVH BY MANDT HITYP KUNNR VKORG VTWEG SPART DATAB.
*
* initialize counter variables for created idocs
CREATED_M_IDOCS = 0.
CREATED_C_IDOCS = 0.
DONE_SINCE_COMMIT = 0.

CLEAR T_CPIDENT. REFRESH T_CPIDENT.

* call of the idoc creator
LOOP AT T_KNVHKEY WHERE MANDT = SY-MANDT.
CLEAR   F_KNVH.
MOVE-CORRESPONDING T_KNVHKEY TO F_KNVH.
* return code is not checked for since no exception is raised by
* the function module.
*
CALL FUNCTION 'ZMASTERIDOC_CREATE_ZDEBHI'
EXPORTING
  KNVHKEY            = F_KNVH
  RCVPFC             = ' '
  RCVPRN             = '         '
  RCVPRT             = ' '
  SNDPFC             = ' '
  SNDPRN             = '         '
  SNDPRT             = ' '
  MESSAGE_TYPE       = MESSAGE_TYPE
IMPORTING
  CREATED_COMM_IDOCS = CREATED_COMM_IDOCS.
*
CREATED_M_IDOCS = CREATED_M_IDOCS + 1.
CREATED_C_IDOCS = CREATED_C_IDOCS + CREATED_COMM_IDOCS.
DONE_SINCE_COMMIT = DONE_SINCE_COMMIT + 1.
*
* append all processed pointer
LOOP AT T_CPIDENT_KNVH WHERE MANDT = F_KNVH-MANDT
                 AND HITYP = F_KNVH-HITYP
                 AND KUNNR = F_KNVH-KUNNR
                 AND VKORG = F_KNVH-VKORG
                 AND VTWEG = F_KNVH-VTWEG
                 AND SPART = F_KNVH-SPART
                 AND DATAB = F_KNVH-DATAB.
*
T_CPIDENT-CPIDENT = T_CPIDENT_KNVH-CPIDENT.
APPEND T_CPIDENT.
*
ENDLOOP.

IF DONE_SINCE_COMMIT >= C_IDOCS_BEFORE_COMMIT.
DONE_SINCE_COMMIT = 0.
*
* write status of all processed pointers
* return code is not checked for since no exception is raised by
* the function module.
CALL FUNCTION 'CHANGE_POINTERS_STATUS_WRITE'
EXPORTING
    MESSAGE_TYPE           = MESSAGE_TYPE
TABLES
    CHANGE_POINTERS_IDENTS = T_CPIDENT.
*
COMMIT WORK.
* return code is not checked for since no exception is raised by
* the function module.
CALL FUNCTION 'DEQUEUE_ALL'.
*
CLEAR T_CPIDENT. REFRESH T_CPIDENT.
*
ENDIF.
*
ENDLOOP.                             "at t_knvhkey
*
* commit if necessary
IF DONE_SINCE_COMMIT > 0.
*
* write status of all processed pointers
* return code is not checked for since no exception is raised by
* the function module.
CALL FUNCTION 'CHANGE_POINTERS_STATUS_WRITE'
EXPORTING
  MESSAGE_TYPE           = MESSAGE_TYPE
TABLES
  CHANGE_POINTERS_IDENTS = T_CPIDENT.
*
COMMIT WORK.
* return code is not checked for since no exception is raised by
* the function module.
CALL FUNCTION 'DEQUEUE_ALL'.
*
ENDIF.
*
MESSAGE ID 'B1' TYPE 'I' NUMBER '038'
WITH CREATED_M_IDOCS MESSAGE_TYPE.
MESSAGE ID 'B1' TYPE 'I' NUMBER '039'
WITH CREATED_C_IDOCS MESSAGE_TYPE.
ENDFUNCTION.

*&———————————————————————*
*&      Form MOVE_X_TO_Y
*&———————————————————————*
*       text
*———————————————————————-*
*      –>P_T_CHGPTRS-TABKEY+20(2) text                               *
*      –>P_F_KNVHKEY-SPART text                                      *
*———————————————————————-*
FORM MOVE_X_TO_Y USING X Y.
*
Y = X.
*
ENDFORM.                               " MOVE_X_TO_Y
*&———————————————————————*
*&      Form CONVERT_CDCHGID_TO_MSGFN
*&———————————————————————*
*       text
*———————————————————————-*
*      –>P_T_CHGPTRS-CDCHGID text                                    *
*      –>P_T_KNVHKEY-MSGFN text                                      *
*———————————————————————-*
FORM CONVERT_CDCHGID_TO_MSGFN USING CDCHGID LIKE BDCP-CDCHGID
                        MSGFN LIKE Z1KNVHM-MSGFN.
*
MSGFN = SPACE.
*
CASE CDCHGID.
WHEN 'I'.
MSGFN = C_MSGFN_I.
WHEN 'U'.
MSGFN = C_MSGFN_U.
WHEN ' '.
MSGFN = C_MSGFN_R.
WHEN 'D'.
MSGFN = C_MSGFN_D.
WHEN 'E'.
MSGFN = C_MSGFN_D.
WHEN 'S'.
MSGFN = C_MSGFN_S.
ENDCASE.
*
ENDFORM.                               " CONVERT_CDCHGID_TO_MSGFN
*&———————————————————————*
*&      Form FILL_SEGMENT_Z1KNVHM
*&———————————————————————*
*       text
*———————————————————————-*
*      –>P_KNVHKEY-MSGFN text                                        *
*———————————————————————-*
FORM FILL_SEGMENT_Z1KNVHM USING MSGFN.
*
CLEAR Z1KNVHM.
*
Z1KNVHM-MSGFN = MSGFN.
Z1KNVHM-HITYP = KNVH-HITYP.
Z1KNVHM-KUNNR = KNVH-KUNNR.
Z1KNVHM-VKORG = KNVH-VKORG.
Z1KNVHM-VTWEG = KNVH-VTWEG.
Z1KNVHM-SPART = KNVH-SPART.
Z1KNVHM-DATAB = KNVH-DATAB.
Z1KNVHM-DATBI = KNVH-DATBI.
Z1KNVHM-HKUNNR = KNVH-HKUNNR.
Z1KNVHM-HVKORG = KNVH-HVKORG.
Z1KNVHM-HVTWEG = KNVH-HVTWEG.
Z1KNVHM-HSPART = KNVH-HSPART.
Z1KNVHM-GRPNO = KNVH-GRPNO.
Z1KNVHM-BOKRE = KNVH-BOKRE.
Z1KNVHM-PRFRE = KNVH-PRFRE.
Z1KNVHM-HZUOR = KNVH-HZUOR.
*
ENDFORM.                               " FILL_SEGMENT_Z1KNVHM

Form Routine for KUNHIER update Function Module

admin — Sun, 30 May 2010 21:13:26 +0000

Note: ABAP/4 is the proprietary programming language of SAP™

The following code is a sample for modifying SAP™ standard program RVKNVH00 and may

need to be adjusted according to your requirements. This code was developed based on

pieces of code present in similar SAP™ standard programs for updating/creating change

documents, such as the one for Customer Master.

IF CHANGE_LINK = 'X'.
CALL FUNCTION 'CUSTOMER_HIERARCHY_UPDATE' IN UPDATE TASK
TABLES
  T_XKNVH = XVKNVH
  T_YKNVH = YKNVH.
***** Insert code here *************************************************
* This block of code has been added to create Change Documents         *
* on CDHDR/CDPOS tables via the function module –                      *
* KUNHIER_WRITE_DOCUMENT (called in the form).                         *
* XVKNVH is the new image of changes, whereas YKNVH is the old image. *
* For every line of change in XVKNVH with a corresponding old image in *
* YKNVH, a Change Document is written.                                 *
************************************************************************
LOOP AT XVKNVH.
CLEAR: I_XVKNVH, I_YVKNVH.
REFRESH: I_XVKNVH, I_YVKNVH.
I_XVKNVH = XVKNVH.
APPEND I_XVKNVH.
READ TABLE YKNVH WITH KEY
     MANDT = XVKNVH-MANDT
     HITYP = XVKNVH-HITYP
     KUNNR = XVKNVH-KUNNR
     VKORG = XVKNVH-VKORG
     VTWEG = XVKNVH-VTWEG
     SPART = XVKNVH-SPART
     DATAB = XVKNVH-DATAB.
IF SY-SUBRC EQ 0.
I_YVKNVH = YKNVH.
APPEND I_YVKNVH.
ENDIF.
PERFORM CD_CALL_KUNHIER
  TABLES I_XVKNVH
         I_YVKNVH
  USING 'U' I_XVKNVH-KUNNR.
ENDLOOP.
*****
***** Code changes end here ********************************************
*—— Änderungsmeldungen ausgeben ———————————–
MESSAGE S028.
ELSE.
MESSAGE S033.
ENDIF.
Figure 5-3: Changes to program RVKNVH00

Figure 5-4: Form Routine for KUNHIER update Function Module
************ Insert Form here ******************************************
******* Form routine to create change documents. This function module *
******* was "generated" based on CD object KUNHIER.                    *
************************************************************************
FORM CD_CALL_KUNHIER
TABLES FXKNVH STRUCTURE VKNVH
        FYKNVH STRUCTURE VKNVH
USING UPD_KNVH OBJECTID.
***
IF   ( UPD_KNVH       NE SPACE ).
CALL FUNCTION 'SWE_REQUESTER_TO_UPDATE'.
CALL FUNCTION 'KUNHIER_WRITE_DOCUMENT        ' IN UPDATE TASK
EXPORTING
  OBJECTID                = OBJECTID
  TCODE                   = 'VDH1'
  UTIME                   = SY-UZEIT
  UDATE                   = SY-DATUM
  USERNAME                = SY-UNAME
  PLANNED_CHANGE_NUMBER   = SPACE
  OBJECI_CHANGE_INDICATOR = 'U'
  PLANNED_OR_REAL_CHANGES = SPACE
  UPD_KNVH                = UPD_KNVH
  UPD_ICDTXI_KUNHIER      = SPACE
TABLES
  ICDTXI_KUNHIER          = I_ICDTXI_KUNHIER
  XKNVH                   = FXKNVH
  YKNVH                   = FYKNVH.
ENDIF.
ENDFORM.

Change Document Update Function Module for Customer Hierarchy

admin — Sun, 30 May 2010 21:12:15 +0000

Note: ABAP/4 is the proprietary programming language of SAP™

This function module was generated using transaction SCDO for Change Document (CD) object

KUNHIER.

FUNCTION KUNHIER_WRITE_DOCUMENT .

CALL FUNCTION 'CHANGEDOCUMENT_OPEN'
   EXPORTING OBJECTCLASS = 'KUNHIER   '
             OBJECTID    = OBJECTID
     PLANNED_CHANGE_NUMBER = PLANNED_CHANGE_NUMBER
PLANNED_OR_REAL_CHANGES = PLANNED_OR_REAL_CHANGES
   EXCEPTIONS SEQUENCE_INVALID = 1
              OTHERS           = 2.

CASE SY-SUBRC.
WHEN 1. MESSAGE A001 WITH 'SEQUENCE INVALID'.
WHEN 2. MESSAGE A001 WITH 'OPEN ERROR'.
ENDCASE.

IF UPD_KNVH       NE SPACE.
CALL FUNCTION 'CHANGEDOCUMENT_MULTIPLE_CASE'
     EXPORTING TABLENAME           = 'KNVH      '
                CHANGE_INDICATOR    = UPD_KNVH
                DOCU_DELETE         = 'X'
     TABLES     TABLE_OLD           = YKNVH
                TABLE_NEW           = XKNVH
     EXCEPTIONS NAMETAB_ERROR       = 1
                OPEN_MISSING        = 2
                POSITION_INSERT_FAILED = 3
                OTHERS              = 4.

CASE SY-SUBRC.
WHEN 1. MESSAGE A001 WITH 'NAMETAB-ERROR'.
WHEN 2. MESSAGE A001 WITH 'OPEN MISSING'.
WHEN 3. MESSAGE A001 WITH 'INSERT ERROR'.
WHEN 4. MESSAGE A001 WITH 'MULTIPLE ERROR'.
ENDCASE.
ENDIF.

IF UPD_ICDTXT_KUNHIER    NE SPACE.
CALL FUNCTION 'CHANGEDOCUMENT_TEXT_CASE'
         TABLES    TEXTTABLE = ICDTXT_KUNHIER
     EXCEPTIONS OPEN_MISSING        = 1
                POSITION_INSERT_FAILED = 2
                OTHERS              = 3.

CASE SY-SUBRC.
WHEN 1. MESSAGE A001 WITH 'OPEN MISSING'.
WHEN 2. MESSAGE A001 WITH 'INSERT ERROR'.
WHEN 3. MESSAGE A001 WITH 'TEXT ERROR'.
ENDCASE.
ENDIF.

CALL FUNCTION 'CHANGEDOCUMENT_CLOSE'
  EXPORTING OBJECTCLASS    = 'KUNHIER   '
             OBJECTID       = OBJECTID
             DATE_OF_CHANGE = UDATE
             TIME_OF_CHANGE = UTIME
             TCODE          = TCODE
             USERNAME       = USERNAME
OBJECT_CHANGE_INDICATOR = OBJECT_CHANGE_INDICATOR
  EXCEPTIONS HEADER_INSERT_FAILED = 1
             OBJECT_INVALID       = 2
             OPEN_MISSING         = 3
             NO_POSITION_INSERTED = 4
             OTHERS               = 5.

CASE SY-SUBRC.
WHEN 1. MESSAGE A001 WITH 'INSERT HEADER FAILED'.
WHEN 2. MESSAGE A001 WITH 'OBJECT INVALID'.
WHEN 3. MESSAGE A001 WITH 'OPEN MISSING'.
WHEN 5. MESSAGE A001 WITH 'CLOSE ERROR'.
ENDCASE.

ENDFUNCTION.

Sample IDOC shell program

admin — Sun, 30 May 2010 21:11:13 +0000

Note: ABAP/4 is the proprietary programming language of SAP™

REPORT ZWMMBXY1.
*
************************************************************************
*** This is an IDOC shell program to create WMMBID01 IDocs for       ***
*** the Goods Movement interface between an external warehouse       ***
*** management system and SAP R/3's Inventory Management module.     ***
************************************************************************

TABLES :
E2MBXYH,                " WMMBID01 IDoc type's header segment
E2MBXYI.                " WMMBID01 IDoc type's detail segment
*      idoc control record
DATA: BEGIN OF IDOC_CONTROL.
INCLUDE STRUCTURE EDI_DC.
DATA: END OF IDOC_CONTROL.

*      idoc data record
DATA: BEGIN OF INT_EDIDD.
INCLUDE STRUCTURE EDI_DD.
DATA: END OF INT_EDIDD.
*
PARAMETERS:
* SAP IM Inbound Test file of IDocs
OUTFILE(40) TYPE C LOWER CASE     " output filename
           DEFAULT '/home/rajcast/invadj50.tst'.
*
START-OF-SELECTION.
*
***** Open the output file
*
OPEN DATASET OUTFILE FOR OUTPUT IN TEXT MODE.
IF SY-SUBRC NE 0.
WRITE: / 'Error opening outfile!', SY-SUBRC.
EXIT.
ENDIF.
*******
CLEAR: IDOC_CONTROL, INT_EDIDD.
************************************************************************
*     SET CONTROL VARIABLES AND WRITE CONTROL RECORD
************************************************************************
*
IDOC_CONTROL-TABNAM     = 'EDI_DC'.          "Table name
IDOC_CONTROL-MANDT      = SY-MANDT.          "Client
IDOC_CONTROL-DOCREL     = SY-SAPRL.          "SAP release
* IDOC_CONTROL-DOCNUM     =                    "edi docnumber
IDOC_CONTROL-DOCTYP     = 'WMMBID01'.        "IDOC type
IDOC_CONTROL-DIRECT     = '2'.               "Direction
IDOC_CONTROL-RCVPOR     = 'SAPBK1'.      "Receiver Port
IDOC_CONTROL-RCVPRT     = 'LS'.              "Receiver Partner Type
IDOC_CONTROL-RCVPRN     = 'BK1CLNT010'.      "Receiver Partner
IDOC_CONTROL-SNDPOR     = 'SAPBK1'.          " Sender port
IDOC_CONTROL-SNDPRT     = 'LS'.              "Partner Type for sender
IDOC_CONTROL-SNDPRN     = 'GOODSMVT01'.      "Sender Partner
IDOC_CONTROL-SNDPFC     = SPACE.             "Sender Partner, function
IDOC_CONTROL-MESTYP     = 'WMMBXY'.          "Message type
IDOC_CONTROL-IDOCTYP    = 'WMMBID01'.        "IDOC type
* IDOC_CONTROL-CIMTYP     =                    "Extension type
* IDOC_CONTROL-SERIAL     =                    "Serial number for serlzn
*
TRANSFER IDOC_CONTROL TO OUTFILE.            "write control record
IF SY-SUBRC NE 0.
WRITE: / 'ERROR EDIDC 1'.
ENDIF.

************************************************************************
************************************************************************
CLEAR INT_EDIDD.
INT_EDIDD-TABNAM     = 'EDI_DD'.
INT_EDIDD-SEGNAM     = 'E2MBXYH'.
* INT_EDIDD-SEGNUM     =
* INT_EDIDD-PSGNUM     =
* INT_EDIDD-HLEVEL     =
*
CLEAR: E2MBXYH.
*
E2MBXYH-BLDAT = '19980825'. "         8   Document date in document
E2MBXYH-BUDAT = '19980825'. "         8   Posting data in document
E2MBXYH-XBLNR = 'testgood'.    "     16   Reference document number
E2MBXYH-BKTXT = 'testgdsrecp'. "     25   Document header text
*E2MBXYH-FRBNR            CHAR C     16   Number of bill of lading
*E2MBXYH-XABLN            CHAR C     10   Goods receipt/issue slip
E2MBXYH-TCODE = 'MB1C'. " CHAR C      4   Session: Current transaction
*
INT_EDIDD-SDATA = E2MBXYH.
*
TRANSFER INT_EDIDD TO OUTFILE.
IF SY-SUBRC NE 0.
WRITE: / 'Error writing EDIDD 1'.
ENDIF.
*
CLEAR INT_EDIDD.
INT_EDIDD-TABNAM     = 'EDI_DD'.
INT_EDIDD-SEGNAM     = 'E2MBXYI'.
* INT_EDIDD-SEGNUM     =
* INT_EDIDD-PSGNUM     =
* INT_EDIDD-HLEVEL     =
*
CLEAR E2MBXYI.
*
*2MBXYI-BEAKZ             CHAR C      1        Indicator: line already e
*2MBXYI-XSTOB             CHAR C      1        Flag: Reverse posting
E2MBXYI-MATNR = '000000TESTMATERIAL'. "rial number
E2MBXYI-WERKS = 'PLNT'. " CHAR C      4        Plant
E2MBXYI-LGORT = '0001'. "                      Storage Location
E2MBXYI-CHARG = 'TESTBTCH'. "                  Batch number
E2MBXYI-BWART = '561'.    "           3        Movement type (inventory
*2MBXYI-INSMK = 'S'.    " CHAR C      1       stock type
*2MBXYI-SOBKZ             CHAR C      1        Special stock indicator
*2MBXYI-KZVBR             CHAR C      1        Indicator: consumption po
*2MBXYI-LIFNR             CHAR C     10        Vendor (creditor) account
*2MBXYI-KUNNR             CHAR C     10        Customer number
*2MBXYI-KDAUF             CHAR C     10        Sales order number
*2MBXYI-KDPOS             CHAR C      6        Item number in customer o
*2MBXYI-KDEIN             CHAR C      4        Scheduling of customer or
*2MBXYI-SHKZG             CHAR C      1        Debit/credit indicator
*2MBXYI-WAERS             CHAR C      5        Currency key
*2MBXYI-DMBTR             CHAR C     15        Amount in local currency
*2MBXYI-BWTAR             CHAR C     10        Valuation type
E2MBXYI-ERFMG = '555.000'. "                   Quantity in unit of entry
E2MBXYI-ERFME = 'CS'. "   CHAR C      3        Unit of entry in char.for
*2MBXYI-BPMNG             CHAR C     15        Quantity in order price q
*2MBXYI-BPRME             CHAR C      3        Order price quantity unit
*2MBXYI-EBELN =                "     10        Purchasing docum
*2MBXYI-EBELP =                "      5        Item number of purchasing
*2MBXYI-ELIKZ = 'X'. "    CHAR C      1        "Delivery completed" indi
*2MBXYI-SGTXT             CHAR C     50        Line item text
*2MBXYI-WEMPF             CHAR C     12        Goods recipient
*2MBXYI-ABLAD             CHAR C     25        Unloading point
*2MBXYI-KOSTL             CHAR C     10        Cost center
*2MBXYI-AUFNR =                   " 12        Order Number
*2MBXYI-ANLN1             CHAR C     12        Asset main number
*2MBXYI-ANLN2             CHAR C      4        Asset sub-number
*2MBXYI-RSNUM             CHAR C     10        Number of reservation / d
*2MBXYI-RSPOS             CHAR C      4        Item number of reservatio
*2MBXYI-KZEAR             CHAR C      1        Indicator: final issue fo
*2MBXYI-UMMAT             CHAR C     18        Receiving/issuing materia
*2MBXYI-UMWRK =         " CHAR C      4        Receiving Plant/Issuing P
*2MBXYI-UMLGO = ' '. "        C      4        Receiving/Issuing Storage
*2MBXYI-UMCHA             CHAR C     10        Receiving/Issuing Batch
*2MBXYI-KZBEW =       "   CHAR C      1        Movement Indicator
*2MBXYI-WEUNB             CHAR C      1        Indicator: goods receipt
*2MBXYI-LGNUM             CHAR C      3        Warehouse number/complex
*2MBXYI-LGTYP             CHAR C      3        Storage type
*2MBXYI-LGPLA             CHAR C     10        Storage bin
*2MBXYI-GRUND =          "            4        Indicator:Reason for Good
*2MBXYI-EVERS             CHAR C      2        Shipping instructions
*2MBXYI-EVERE             CHAR C      2        Compliance with shipping
*2MBXYI-IMKEY             CHAR C      8        Internal key for real est
*2MBXYI-KSTRG             CHAR C     12        Cost object
*2MBXYI-PAOBJNR           CHAR C     10        Number for business segme
*2MBXYI-PRCTR             CHAR C     10        Profit center
*2MBXYI-PS_PSP_PNR        CHAR C      8        Project structure plan el
*2MBXYI-NPLNR             CHAR C     12        Network number for accoun
*2MBXYI-AUFPL             CHAR C     10        Planning number for trans
*2MBXYI-APLZL             CHAR C      8        Counter for distinguishin
*2MBXYI-AUFPS             CHAR C      4        Number of order item in C
*2MBXYI-VPTNR             CHAR C     10        Partner account number
*2MBXYI-FIPOS             CHAR C     14        Commitment item
*2MBXYI-GSBER             CHAR C      4        Business area
*2MBXYI-BSTMG             CHAR C     15        Goods receipt quantity in
*2MBXYI-BSTME             CHAR C      3        Order unit
*2MBXYI-EXBWR             CHAR C     15        Posting amount in local c
*2MBXYI-KONTO             CHAR C     10        G/L account number
*2MBXYI-RSHKZ             CHAR C      1        Debit/credit indicator
*2MBXYI-BDMNG             CHAR C     15        Requirement quantity in C
*2MBXYI-ENMNG             CHAR C     15        Issued quantity in char.f
*2MBXYI-QPLOS             CHAR C     12        Inspection lot number in
*2MBXYI-UMZST             CHAR C      1        Status of receiving batch
*2MBXYI-UMZUS             CHAR C      1        Status key of transfer ba
*2MBXYI-UMBAR             CHAR C     10        Valuation type of transfe
**MBXYI-UMSOK             CHAR C      1        Special stock indicator f
*2MBXYI-LFBJA             CHAR C      4        Fiscal year of a referenc
*2MBXYI-LFBNR             CHAR C     10        Document number of a refe
*2MBXYI-LFPOS             CHAR C      4        Item in a reference docum
*2MBXYI-SJAHR             CHAR C      4        Material document year in
*2MBXYI-SMBLN             CHAR C     10        Number of a material docu
*2MBXYI-SMBLP             CHAR C      4        Item in material document
*2MBXYI-EXVKW             CHAR C     15        Sales value specified ext
*2MBXYI-QM_ZUSTD          CHAR C      1        Batch status with status
*2MBXYI-POSNR             CHAR C      6        Delivery item for subsyst
*2MBXYI-VBELN             CHAR C     10        Delivery
*2MBXYI-QM_UMZST          CHAR C      1        Status of receiv. batch w
*2MBXYI-BWLVS             CHAR C      3        Movement type for Whse Mg
*2MBXYI-UMREZ = '   '. " CHAR C      5        NUMERATOR FOR CONVERTING
*2MBXYI-UMREN = '   '. " CHAR C      5        DENOMINATOR FOR CONVERSIO
*2MBXYI-VFDAT = '        '. "         8        EXPIRATION DATE OR BEST-B
*2MBXYI-DABRZ             DATS D      8        Reference date for accoun
*
******************************** write EDIDD record ********************
INT_EDIDD-SDATA = E2MBXYI.
TRANSFER INT_EDIDD TO OUTFILE.
IF SY-SUBRC NE 0.
WRITE: / 'ERROR EDIDD 2'.
ENDIF.

Status codes

admin — Sun, 30 May 2010 21:10:34 +0000

Status codes

Following is a list of status codes with descriptions.

Direction: 1 = Outbound, 2 = Inbound

Processing Level: A = SAP Application
I = IDOC Interface
S = External system / EDI Subsystem

————————————————————————————————–
| |IDoc status|Direction|Proc. level|Description                                                 |
————————————————————————————————–
| |00         |1        |I          |Not used, only R/2                                          |
| |01         |1        |I          |IDoc created                                                |
| |02         |1        |I          |Error passing data to port                                  |
| |03         |1        |I          |Data passed to port OK                                      |
| |04         |1        |S          |Error within control information of EDI subsystem           |
| |05         |1        |S          |Error during translation                                    |
| |06         |1        |S          |Translation OK                                              |
| |07         |1        |S          |Error during syntax check                                   |
| |08         |1        |S          |Syntax check OK                                             |
| |09         |1        |S          |Error during interchange handling                           |
| |10         |1        |S          |Interchange handling OK                                     |
| |11         |1        |S          |Error during dispatch                                       |
| |12         |1        |S          |Dispatch OK                                                 |
| |13         |1        |S          |Retransmission OK                                           |
| |14         |1        |S          |Interchange Acknowledgement positive                        |
| |15         |1        |S          |Interchange Acknowledgement negative                        |
| |16         |1        |S          |Functional Acknowledgement positive                         |
| |17         |1        |S          |Functional Acknowledgement negative                         |

Data contained in this appendix has been obtained from SAP™ Systems’ tables of values.

| |18         |1        |I          |Triggering EDI subsystem OK                                 |
| |19         |1        |I          |Data transfer for test OK                                   |
| |20         |1        |I          |Error triggering EDI subsystem                              |
| |21         |1        |I          |Error passing data for test                                 |
| |22         |1        |S          |Dispatch OK, acknowledgement still due                      |
| |23         |1        |S          |Error during retransmission                                 |
| |24         |1        |S          |Control information of EDI subsystem OK                     |
| |25         |1        |I          |Processing despite syntax error (outbound)                  |
| |26         |1        |I          |Error during syntax check of IDoc (outbound)                |
| |27         |1        |I          |Error in dispatch level (ALE service)                       |
| |28         |1        |I          |Not used                                                    |
| |29         |1        |I          |Error in ALE service                                        |
| |30         |1        |I          |IDoc ready for dispatch (ALE service)                       |
| |31         |1        |I          |Error – no further processing                               |
| |32         |1        |I          |IDoc was edited                                             |
| |33         |1        |I          |Original of an IDoc which was edited                        |
| |34         |1        |I          |Error in control record of IDoc                             |
| |35         |1        |I          |IDoc reloaded from archive                                  |
| |36         |1        |S          |Electronic signature not performed (timeout)                |
| |37         |1        |I          |IDoc added incorrectly                                      |
| |38         |1        |I          |IDoc archived                                               |
| |39         |1        |I          |Receipt confirmed by target system                          |
| |40         |1        |I          |Application document not created in target system           |
| |41         |1        |I          |Application document created in target system               |
| |50         |2        |I          |IDoc added                                                  |
| |51         |2        |A          |Error: Application document not posted                      |
| |52         |2        |A          |Application document not fully posted                       |
| |53         |2        |A          |Application document posted                                 |
| |54         |2        |A          |Error during formal application check                       |
| |55         |2        |A          |Formal application check OK                                 |
| |56         |2        |I          |IDoc with errors added                                      |
| |57         |2        |A          |Test IDoc: Error during application check                   |
| |58         |2        |I          |Not used                                                    |
| |59         |2        |I          |Not used                                                    |
| |60         |2        |I          |Error during syntax check of IDoc (inbound)                 |
| |61         |2        |I          |Processing despite syntax error (inbound)                   |
| |62         |2        |I          |IDoc passed to application                                  |
| |63         |2        |I          |Error passing IDoc to application                           |
| |64         |2        |I          |IDoc ready to be passed to application                      |
| |65         |2        |I          |Error in ALE service                                        |
| |66         |2        |I          |Not used                                                    |
| |67         |2        |I          |Not used                                                    |
| |68         |2        |I          |Error – no further processing                               |
| |69         |2        |I          |IDoc was edited                                             |
| |70         |2        |I          |Original of an IDoc which was edited                        |
| |71         |2        |I          |IDoc reloaded from archive                                  |
| |72         |2        |I          |Not used, only R/2                                          |
| |73         |2        |I          |IDoc archived